!!==============================================================================
!!
!!	LA PEQUEÑA CERILLERA:
!!	Extensiones a la librería
!!
!!==============================================================================
!!
!!
!!	File:			cerillera_lib.inf
!!	Author(s):		J. Francisco Martín (jfm.lisaso@gmail.com)
!!	Cover-art:		Anne Anderson
!!	Language:		ES (Castellano)
!!	System:			Inform/INFSP 6
!!	Platform:		Máquina-Z
!!	Release:		1.2
!!	Released:		2010/12/13
!!
!!
!!------------------------------------------------------------------------------
!!
!!
!!	Este programa es software libre: usted puede redistribuirlo y/o 
!!	modificarlo bajo los términos de la Licencia Pública General GNU 
!!	publicada por la Fundación para el Software Libre, ya sea la versión 
!!	3 de la Licencia, o (a su elección) cualquier versión posterior.
!!
!!	Este programa se distribuye con la esperanza de que sea útil, pero 
!!	SIN GARANTÍA ALGUNA; ni siquiera la garantía implícita MERCANTIL o 
!!	de APTITUD PARA UN PROPÓSITO DETERMINADO. Consulte los detalles de 
!!	la Licencia Pública General GNU para más información.
!!
!!	Debería haber recibido una copia de la Licencia Pública General GNU 
!!	junto a este programa. En caso contrario, consulte
!!	<http://www.gnu.org/licenses/>.
!!
!!	Copyright (c) 2010, J. Francisco Martín
!!
!!
!!==============================================================================


!!------------------------------------------------------------------------------
!! Información básica sobre el relato, en castellano
!!------------------------------------------------------------------------------
[ Banner i;
	#Ifdef TARGET_ZCODE;		!!
	style bold;					!!
	#Ifnot;						!! NEGRITA
	glk($0086, 3);				!!
	#Endif;						!!
	if (Story ~= 0 ) print (string) story;
	#Ifdef	TARGET_ZCODE;		!!
	font on; style roman;		!!
	#Ifnot;						!! NORMAL
	glk($0086, 0);				!!
	#Endif;						!!
	new_line;
	if ( Headline ~= 0 ) print (string) Headline;
	new_line;
	#Ifdef DEBUG;
	print "Versión BETA";
	#Ifnot;
	#Ifdef TARGET_ZCODE;
	print "Versión ", Checking ,".";
	print (HDR_GAMERELEASE-->0) & $03ff;
	#Ifnot;	! TARGET_GLULX;
	print "Versión ", Checking ,".";
	@aloads ROM_GAMERELEASE 0 i;
	print i;
	#Endif;	! TARGET_
	#Endif;	! DEBUG
	print " / Núm. de serie ";
	for (i=0 : i<6 : i++) print (char) HDR_GAMESERIAL->i;	!!in!!
	print " / Creado con Inform ";
	if (Headline == 0) print "v. ";
	inversion;
	new_line;
];


!!------------------------------------------------------------------------------
!! Elimina la barra de estado (crea una barra de estado sin altura)
!!------------------------------------------------------------------------------
[ DrawStatusLine;
	StatusLineHeight( 0 );
	MainWindow();
];


!!------------------------------------------------------------------------------
!! Redefinición de los 'lookmode': Breve, Largo y Superbreve
!!------------------------------------------------------------------------------
[ LMode1Sub; lookmode = 1; L__M( ##LMode1 ); ];	! Breve
[ LMode2Sub; lookmode = 2; L__M( ##LMode2 ); ];	! Largo (normal)
[ LMode3Sub; lookmode = 3; L__M( ##LMode3 ); ];	! Superbreve


!!------------------------------------------------------------------------------
!! Redefinición de LookSub: ahora no imprime el nombre de la localidad actual
!!------------------------------------------------------------------------------
[ LookSub allow_abbrev visibility_levels i j k nl_flag;
	if ( parent(player) == 0 ) return RunTimeError( 10 );
   .MovedByInitial;

	if ( location == thedark ) { visibility_ceiling = thedark; NoteArrival(); }
	else {
		visibility_levels = FindVisibilityLevels();
		if ( visibility_ceiling == location ) {
			NoteArrival();
			if ( visibility_ceiling ~= location ) jump MovedByInitial;
		}
	}

	! Se omite la impresión de la línea superior. e.g.
	! Octogonal Room (on the table) (as Frodo)

	! The room description (if visible)
	if (lookmode < 3 && visibility_ceiling == location) {
		if ((allow_abbrev ~= 1) || (lookmode == 2) || (location hasnt visited)){
			if (location.&describe ~= 0) RunRoutines(location, describe);
			else {
				if (location.description == 0) RunTimeError(11, location);
				else PrintOrRun(location, description);
			}
		}
	}

	if (visibility_ceiling == location) nl_flag = 1;
	if (visibility_levels == 0) Locale(thedark);
	else {
		for (i=player,j=visibility_levels : j>0 : j--,i=parent(i))
		give i workflag;

		for (j=visibility_levels : j>0 : j--) {
			for (i=player,k=0 : k<j : k++) i=parent(i);
			if (i.inside_description ~= 0) {
				if (nl_flag) new_line; else nl_flag = 1;
				PrintOrRun(i,inside_description); }
			if (Locale(i)~=0) nl_flag=1;
		}
	}

	LookRoutine();
	ScoreArrival();
	action = ##Look;
	if (AfterRoutines() == 1) rtrue;
]; !in


!!------------------------------------------------------------------------------
!! Información más exhaustiva sobre el relato, en castellano
!!------------------------------------------------------------------------------
[ VersionSub ix;
	new_line; Banner(); new_line;
	print "Versión de la librería Inform ", (string) LibRelease;
	print " / Núm. de serie librería ", (string) LibSerial;
	new_line;
	#Ifdef LanguageVersion;
	print (string) LanguageVersion;
	new_line;
	#Endif; ! LanguageVersion
	#Ifdef TARGET_ZCODE;
	ix = 0; ! shut up compiler warning
	if (standard_interpreter > 0) {
		print "Estándar del intérprete ", standard_interpreter/256, ".",
		standard_interpreter%256 ," (", HDR_TERPNUMBER->0;
		#Iftrue (#version_number == 6);
		print (char) '.', HDR_TERPVERSION->0;
		#Ifnot;
		print (char) HDR_TERPVERSION->0;
		#Endif;
		print ")";
		}
	else {
		print "Intérprete ", HDR_TERPNUMBER->0, " Versión ";
		#Iftrue (#version_number == 6);
		print HDR_TERPVERSION->0;
		#Ifnot;
		print (char) HDR_TERPVERSION->0;
		#Endif;
		print " / ";
	}
	#Ifnot; ! TARGET_GLULX;
	@gestalt 1 0 ix;
	print "Versión del intérprete ", ix / $10000, ".", (ix & $FF00) / $100,
	".", ix & $FF, " / ";
	@gestalt 0 0 ix;
	print "VM ", ix / $10000, ".", (ix & $FF00) / $100, ".", ix & $FF;
	#Endif; ! TARGET_;
	new_line; new_line;
	print "Ilustración de cubierta: Anne Anderson^";
	print "Textos obtenidos de ", (stcursiva) "Wikisource", 
	" (con algunas modificaciones):^";
	print (stcursiva) "http://es.wikisource.org/wiki/La_ni%C3%B1a_de_los_f%C3%B3sforos^";
];